Aptos: Publish a module to save and retrieve messages

• Aptos uses the Move language and “published” modules in place of traditional smart contracts.
• This tutorial shows you how to set up an Aptos node, initialize a Move project, and publish a simple module that stores a string on-chain.
• You’ll run through the basics of module creation, compilation, testing, and then sending transactions to set and retrieve data.
• Use the Aptos CLI for everything from local testing to publishing, and wrap up by querying the on-chain data with Aptos’ REST API.

​

Main article

• Initialize an Aptos project using the Aptos CLI.
• Publish a module on the Aptos testnet.
• Interact with the module to save a message.
• Use the Aptos REST API to retrieve the message.

​

Prerequisites

• Chainstack account to deploy a reliable Aptos RPC endpoint.
• Martian Aptos wallet to receive testnet Aptos token (APT).
• Aptos CLI to compile, publish, and interact with the Move module.

​

Overview

1. With Chainstack, create a public chain project.
2. With Chainstack, join Aptos testnet.
3. With Chainstack, access your Aptos node credentials.
4. Set up your Martian wallet to work through the Chainstack Aptos node.
5. Fund your account through the Aptos testnet faucet.
6. Install the Aptos CLI.
7. Create a Move project.
8. Create and configure your Aptos project.
9. Create a module in the Move language.
10. Compile and test the Move module.
11. Publish the Move module.
12. Save and retrieve a message on the Aptos chain.

​

Step-by-step

​

Create a public chain project

​

Join the Aptos testnet

​

Get node access and credentials

​

Set up Martian wallet

​

Fund your account

​

Install the Aptos CLI

​

Create a Move project

1. In your project directory, create a Move project:
   Shell

   aptos move init --name save-message
   
   where save-message — name of the package. This creates a sources directory and a Move.toml file.
2. Open your Move.toml file and edit it to add [addresses] and [dev-addresses], where:
   • dev = "_" — your default Aptos account.
   • dev = "0xC0FFEE" — an alternative Aptos account for tests.
   Example:
   TOML

   [package]
   name = 'save-message'
   version = '1.0.0'
   
   [addresses]
   dev = "_"
   
   [dev-addresses]
   dev = "0xC0FFEE"
   
   [dependencies.AptosFramework]
   git = 'https://github.com/aptos-labs/aptos-core.git'
   rev = 'main'
   subdir = 'aptos-move/framework/aptos-framework'
   
   Note that packages have one-time names. If you want to re-publish the package, you must change its name.

​

Create and configure an Aptos project

1. In your project directory, run aptos init > custom. This will start a configuration process, during which you need to set up your Chainstack endpoint and Martian wallet private key. Adding the private key will retrieve your Aptos public address automatically.
2. Add your Aptos node endpoint deployed with Chainstack.
3. At the faucet URL request, type skip since you have already funded your account on the previous step.
4. Paste your Martian wallet private key to finish configuring your project. The key is used to send transactions and retrieve your public address. Example of a successful result:
   Shell

   Aptos CLI is now set up for account ...4474 as profile default!  Run `aptos --help` for more information about commands
   {
     "Result": "Success"
   }
   
   As a result, you get a .aptos directory with a config.yaml file inside it. In config.yaml, you will find your project setup.

​

Create a Move module

module dev::message {
    use std::error;
    use std::signer;
    use std::string;
    use aptos_framework::account;
    use aptos_framework::event;

//:!:>resource
    struct MessageHolder has key {
        message: string::String,
        message_change_events: event::EventHandle<MessageChangeEvent>,
    }
//<:!:resource

    struct MessageChangeEvent has drop, store {
        from_message: string::String,
        to_message: string::String,
    }

    /// There is no message present
    const ENO_MESSAGE: u64 = 0;

    public fun get_message(addr: address): string::String acquires MessageHolder {
        assert!(exists<MessageHolder>(addr), error::not_found(ENO_MESSAGE));
        *&borrow_global<MessageHolder>(addr).message
    }

    public entry fun set_message(account: signer, message: string::String)
    acquires MessageHolder {
        let account_addr = signer::address_of(&account);
        if (!exists<MessageHolder>(account_addr)) {
            move_to(&account, MessageHolder {
                message,
                message_change_events: account::new_event_handle<MessageChangeEvent>(&account),
            })
        } else {
            let old_message_holder = borrow_global_mut<MessageHolder>(account_addr);
            let from_message = *&old_message_holder.message;
            event::emit_event(&mut old_message_holder.message_change_events, MessageChangeEvent {
                from_message,
                to_message: copy message,
            });
            old_message_holder.message = message;
        }
    }

    #[test(account = @0x1)]
    public entry fun sender_can_set_message(account: signer) acquires MessageHolder {
        let addr = signer::address_of(&account);
        aptos_framework::account::create_account_for_test(addr);
        set_message(account,  string::utf8(b"Hello Chainstack dev"));

        assert!(
          get_message(addr) == string::utf8(b"Hello Chainstack dev"),
          ENO_MESSAGE
        );
    }
}

​

Compile and test the Move module

1. To compile your Move module, run:
   Shell

   aptos move compile --named-addresses dev=default
   
2. After the module compiled, run a build-in test which checks if the set_message and get_message functions work:
   Shell

   aptos move test
   

​

Publish the Move module

1. Publish your compiled and tested Move module by running:
   Shell

   aptos move publish --named-addresses dev=default
   
2. Type yes to confirm publishing the transaction on the Aptos chain. The module will publish and the terminal will return the module information. You can use the transaction hash to retrieve transaction details. To do so, run:
   cURL

   curl --location --request GET 'YOUR_CHAINSTACK_ENDPOINT/v1/transactions/by_hash/0x815cecb01a962331ca34904653a26715e6cd8e631d2d1b7da17b593adda1ea65' \
   --header 'Content-Type: application/json'
   
   where YOUR_CHAINSTACK_ENDPOINT is your Aptos node endpoint you used earlier.

​

Save and retrieve a message on the Aptos chain

1. To save a message on the Aptos chain, run:
   Shell

   aptos move run --function-id 'default::message::set_message' --args 'string:Hello Chainstack dev'
   
   where:
   • run — a Move command to call functions
   • function-id — a function to call
   • args — arguments of the function
2. Type yes to confirm publishing the transaction on the Aptos chain.
3. Retrieve the published message via the REST API by running:
   cURL

   curl --location --request GET 'YOUR_CHAINSTACK_ENDPOINT/v1/accounts/c0e0ce57eaf9680ae67252fb3126f25aa86bb098b05f7b72cf0cf0de57c72a7f/resource/0xc0e0ce57eaf9680ae67252fb3126f25aa86bb098b05f7b72cf0cf0de57c72a7f::message::MessageHolder'    \
   --header 'Content-Type: application/json'
   
   where YOUR_CHAINSTACK_ENDPOINT is your Aptos node endpoint you used earlier.

{
    "type": "0xc0e0ce57eaf9680ae67252fb3126f25aa86bb098b05f7b72cf0cf0de57c72a7f::message::MessageHolder",
    "data": {
        "message": "Hello Chainstack dev",
        "message_change_events": {
            "counter": "0",
            "guid": {
                "id": {
                    "addr": "0xc0e0ce57eaf9680ae67252fb3126f25aa86bb098b05f7b72cf0cf0de57c72a7f",
                    "creation_num": "4"
                }
            }
        }
    }
}

​

Conclusion

​

About the author

Davide Zambiasi

Developer Advocate @ Chainstack
BUIDLs on EVM, The Graph protocol, and Starknet
Helping people understand Web3 and blockchain development